// datatypes.dmodel, the first file
    datatype String

    // commons.dmodel, the second file
    package my.company.common {
       entity HasAuthor {
          author: String
       }
    }

    // blogs.dmodel, the third file
    package my.company.blog {
       import my.company.common.*
       entity Blog {
          title: String
          many posts: Post
       }
       entity Post extends my.company.common.HasAuthor {
          title: String
          content: String
          many comments: Comment
       }
       entity Comment extends HasAuthor {
          content: String
       }
    }

grammar org.example.domainmodel.Domainmodel with
    org.eclipse.xtext.common.Terminals
     
    generate domainmodel "www.example.org/domainmodel/Domainmodel"
     
    Domainmodel:
       (elements += AbstractElement)*
    ;
     
    PackageDeclaration:
        'package' name = QualifiedName '{'
           (elements += AbstractElement)*
        '}'
    ;
     
    AbstractElement:
        PackageDeclaration | Type | Import
    ;
     
    QualifiedName:
        ID ('.' ID)*
    ;
     
    Import:
       'import' importedNamespace = QualifiedNameWithWildcard
    ;
    QualifiedNameWithWildcard:
        QualifiedName '.*'?
    ;
    Type:
        DataType | Entity
    ;
    DataType:
        'datatype' name=ID
    ;
    Entity:
      'entity' name = ID ('extends' superType = [Entity | QualifiedName])? '{'
         (features += Feature)*
      '}'
    ;
    Feature:
        (many ?= 'many')? name = ID ':' type = [Type | QualifiedName]
    ;