Eclipse Community Forums: TMF (Xtext) » What is wrong with my simple grammar ?

Home

Home » Modeling » TMF (Xtext) » What is wrong with my simple grammar ?

What is wrong with my simple grammar ? [message #1064902]

Fri, 21 June 2013 10:59

Eclipse User

Hi,

I'm trying to define a grammar able to support writing the following text:

--NECST HEADER Scripts
#NESCT START
#NECST MIDDLE [free_text1][free_text2]

    --NECST ONE Script
    --NECST TWO Script

#NECST EXIT

For that, I have define the following grammar:

grammar org.xtext.example.mydsl.MyDsl with org.eclipse.xtext.common.Terminals hidden (NECST_PARAM)

generate myDsl "http://www.xtext.org/example/mydsl/MyDsl"

Model:{Model}
	'--NECST HEADER Scripts'
	(commentNecst+=CommandNecst*)?
	scripts+=Script+;
	
CommandNecst:
	'#NECST' command=ENUM_COMMANDNECST param+=NECST_PARAM*;
enum ENUM_COMMANDNECST : START|MIDDLE|EXIT;

Script:
	'--NECST' script=ENUM_SCRIPT 'Script'
;
enum ENUM_SCRIPT : ONE|TWO|THREE;

terminal NECST_PARAM : '[' -> ']';

But, I am not able to type anything after the first line.
What is wrong ?

Thanks

Re: What is wrong with my simple grammar ? [message #1064907 is a reply to message #1064902]

Fri, 21 June 2013 11:15

Eclipse User

Hi,

the problem is the hidden statement it should include ws and others. besides ws in keywords is a bad idea

grammar org.xtext.example.mydsl.MyDsl with org.eclipse.xtext.common.Terminals hidden (NECST_PARAM,WS, ML_COMMENT, SL_COMMENT)

generate myDsl "http://www.xtext.org/example/mydsl/MyDsl"

Model:{Model}
	'--NECST' 'HEADER' 'Scripts'
	(commentNecst+=CommandNecst*)
	scripts+=Script+;
	
CommandNecst:
	'#NECST' command=ENUM_COMMANDNECST param+=NECST_PARAM*;
enum ENUM_COMMANDNECST : START|MIDDLE|EXIT;

Script:
	'--NECST' script=ENUM_SCRIPT 'Script'
;
enum ENUM_SCRIPT : ONE|TWO|THREE;

terminal NECST_PARAM : '[' -> ']';

Re: What is wrong with my simple grammar ? [message #1064924 is a reply to message #1064907]

Fri, 21 June 2013 12:31

Eclipse User

Great Christian, Thanks !

I am now able to write the beginning of my file, except the final "#NECST EXIT".
Can you give me a tip for this issue ?

Thanks

Re: What is wrong with my simple grammar ? [message #1064939 is a reply to message #1064924]

Fri, 21 June 2013 13:57

Eclipse User

your grammar says the file ends with scripts

Re: What is wrong with my simple grammar ? [message #1064950 is a reply to message #1064939]

Fri, 21 June 2013 17:02

Eclipse User

Ok, so I've tried the following:

grammar org.xtext.example.mydsl.MyDsl with org.eclipse.xtext.common.Terminals hidden (NECST_PARAM,WS, ML_COMMENT, SL_COMMENT)

generate myDsl "http://www.xtext.org/example/mydsl/MyDsl"

Model:{Model}
	'--NECST' 'HEADER' 'Scripts'
	commandNecst+=CommandNecst*
	script+=Script+
	e=Exit
;

CommandNecst:
	'#NECST' command=ENUM_COMMANDNECST param+=NECST_PARAM*;
enum ENUM_COMMANDNECST : START|MIDDLE;

Exit:
	'#NECST' 'EXIT'
;

Script:
	'--NECST' script=ENUM_SCRIPT 'Script'
;
enum ENUM_SCRIPT : ON|TWO|THREE;

terminal NECST_PARAM : '[' -> ']';

But after having typed some "Script", the content assist keeps proposing me other "Script" but no "Exit" rule;and I don't know how to do so.

Any Idea ?
Thanks

Re: What is wrong with my simple grammar ? [message #1064958 is a reply to message #1064950]

Fri, 21 June 2013 18:07

Eclipse User

Hi,

you have to define content assist for custom datatype rules yourself by implementing the corresponding method in the proposalprovider
alternatively you can change the datatype rule to a real parser rule e.g.

Exit:
{Exit} '#NECST' 'EXIT'
;

Re: What is wrong with my simple grammar ? [message #1064969 is a reply to message #1064958]

Sat, 22 June 2013 04:12

Eclipse User

Thank you very much Christian, that works fine now !

Previous Topic:	Xtext validation on closed files
Next Topic:	LLVM Suport

Goto Forum:

-=] Back to Top [=-

Current Time: Wed Jul 23 06:50:53 EDT 2025

.:: Contact :: Home ::.

Breadcrumbs

Sign up to our Newsletter