Eclipse Community Forums: TMF (Xtext) » Formatter inner block indentation

Home

Home » Modeling » TMF (Xtext) » Formatter inner block indentation(How to indent a inner block)

Formatter inner block indentation [message #1777109]

Fri, 24 November 2017 09:19

Eclipse User

Hi guys, I can't format the block "entities" below, how I could get this block in my DSLFormatter? Something like:

interior(
	entities.regionFor.keyword('{').prepend[oneSpace].append[newLine],
	entities.regionFor.keyword('}').prepend[newLine],
	[indent]
)

service myService {

	entities {
		
		entity myEntity {
			one
			two
			three
		}
		
	}

}

Re: Formatter inner block indentation [message #1777110 is a reply to message #1777109]

Fri, 24 November 2017 09:25

Eclipse User

you usually format such things at the level where they are e.g.

interior(
service.regionFor.keyword('{'),
service.regionFor.keyword('}')
)[indent]

.....

interior(
entities.regionFor.keyword('{'),
entities.regionFor.keyword('}')
)[indent]
....
interior(
entity.regionFor.keyword('{'),
entity.regionFor.keyword('}')
)[indent]

Re: Formatter inner block indentation [message #1777113 is a reply to message #1777110]

Fri, 24 November 2017 09:56

Eclipse User

Thanks for the answer. In the formatter code I don't have the "entities" object available to do the indentation. Am I doing something wrong in my grammer?

...
Service:
	'service' service=ID '{'
		('entities' '{' (entities+=Entity)* '}')?
	'}'
;

Entity:
...

Re: Formatter inner block indentation [message #1777114 is a reply to message #1777113]

Fri, 24 November 2017 11:08

Eclipse User

you can always fall back to the region finder that uses grammar elements

class MyDslFormatter extends AbstractFormatter2 {

	@Inject extension MyDslGrammarAccess

	def dispatch void format(Service service, extension IFormattableDocument document) {
		service.regionFor.keyword(serviceAccess.leftCurlyBracketKeyword_2).append[newLine]
		service.regionFor.keyword(serviceAccess.rightCurlyBracketKeyword_4).prepend[newLine]
		service.regionFor.keyword(serviceAccess.leftCurlyBracketKeyword_3_1).append[newLine]
		service.regionFor.keyword(serviceAccess.rightCurlyBracketKeyword_3_3).prepend[newLine]
		interior(
			service.regionFor.keyword(serviceAccess.leftCurlyBracketKeyword_2),
			service.regionFor.keyword(serviceAccess.rightCurlyBracketKeyword_4)
		)[indent]
		interior(
			service.regionFor.keyword(serviceAccess.leftCurlyBracketKeyword_3_1),
			service.regionFor.keyword(serviceAccess.rightCurlyBracketKeyword_3_3)
		)[indent]
		for (Entity entity : service.getEntities()) {
			entity.format;
		}
	}

	def dispatch void format(Entity entity, extension IFormattableDocument document) {
		entity.regionFor.keyword(entityAccess.leftCurlyBracketKeyword_2).append[newLine]
		entity.regionFor.keyword(entityAccess.rightCurlyBracketKeyword_4).prepend[newLine]
		interior(
			entity.regionFor.keyword(entityAccess.leftCurlyBracketKeyword_2),
			entity.regionFor.keyword(entityAccess.rightCurlyBracketKeyword_4)
		)[indent]
	}
}

Re: Formatter inner block indentation [message #1777116 is a reply to message #1777114]

Fri, 24 November 2017 11:31

Eclipse User

Thank you so much, your example helped me alot. It's working fine now.

Previous Topic:	Xtext web support into Angular app
Next Topic:	Confusion about two ways to get resourceDescription

Goto Forum:

-=] Back to Top [=-

Current Time: Sat Jul 26 15:07:26 EDT 2025

.:: Contact :: Home ::.

Breadcrumbs

Sign up to our Newsletter