class MyFeatureScopes extends FeatureScopes {
    @Inject private OperatorMapping operatorMapping
    @Inject private extension IQualifiedNameProvider

    // Pattern that describes methods that can be called
    final static val ALLOWED_METHODS = (
        ".*\\.(_?set|_?get).*" + "|" + DataTypeExtensions.canonicalName.quote + "\\..*" + "|" +
        FlowFeatures.canonicalName.quote + "\\..*" + "|" + (AbstractMultiSiteData.canonicalName + ".toString()").quote
        ).compile

    override protected IScope createReceiverFeatureScope(EObject featureCall, XExpression receiver,
        LightweightTypeReference receiverType, JvmIdentifiableElement receiverFeature, boolean implicitReceiver,
        boolean validStatic, TypeBucket receiverBucket, IScope parent, IFeatureScopeSession session) {

        val receiverScope = super.createReceiverFeatureScope(
                featureCall, receiver, receiverType, receiverFeature,
                implicitReceiver, validStatic,  receiverBucket, parent, session)

        // Tailor what methods can be called 
        return new FilteringScope(receiverScope) [
            val obj = it.EObjectOrProxy
            if (obj instanceof JvmOperation) {
                return ALLOWED_METHODS.matcher(obj.identifier).matches
            }
            return true
        ]
    }
}