Eclipse Community Forums: TMF (Xtext) » Alternative types in cross references

Home » Modeling » TMF (Xtext) » Alternative types in cross references(How to distinguish a cross reference with different types)

Alternative types in cross references [message #1115504]

Tue, 24 September 2013 03:33

Eclipse User

Hi all,
I got a grammar for our domain model where I need a cross reference to 2 different types.
In the parser rule ReferenceAttribute I should be able to distinguish between a Java-Type reference and a reference to another DomainObject (from another resource).
Of course it's not possible with an alternative (for the ANTLR parser it's the same thing).

What's the best (most default) way to achieve that?

Here's my simplified grammar:

grammar xy.domaindsl.DomainDSL with org.eclipse.xtext.common.Terminals
   hidden(WS, ML_COMMENT, NUM_COMMENT)

import "http://www.eclipse.org/framework/v1.0/DomainDSL" // It's of course not eclipse.org  :d 
import "http://www.eclipse.org/emf/2002/Ecore" as ecore
import "http://www.eclipse.org/xtext/common/JavaVMTypes" as java

DomainModel:
   'package' name = QualifiedName ';'

   imports  += TypeImportDeclaration*
   elements += DomainObject*
;

TypeImportDeclaration:
   'import' importedNamespace = QualifiedName ';'
;

DomainObject:
   'bo' name = ID ('extends' superType = [BusinessObject|QualifiedName])?
   '{'
      description = MultipleSLComment?
      (attributes += Attribute)* 
   '}'
;

Attribute:
   (
      ReferenceAttribute     |
      ... other alternative attributes
   )
   description = SL_COMMENT?
;

ReferenceAttribute:
   type = ([DomainObject|QualifiedName] | [java::JvmGenericType|QualifiedName]) // That's the kind of thing I'd like to have
   name = ID
;

Thanks a lot for any help
Peter

Re: Alternative types in cross references [message #1115670 is a reply to message #1115504]

Tue, 24 September 2013 08:15

Eclipse User

Hi,

this is afaik not possible. (parsing is done before linking.
you need either a common supertype or a kind of syntactic difference e.g. a prefix.

Re: Alternative types in cross references [message #1115676 is a reply to message #1115670]

Tue, 24 September 2013 08:25

Eclipse User

Hi Christian,
thanks for your reply.

As common supertype I have an ecore::EObject. In the attached grammar I just wanted to show what I'd like to have.
So actually the grammar rule looks like this:

ReferenceAttribute:
   type = [ecore::EObject|QualifiedName]
   name = ID
;

The problem is that I don't know exactly how the scoping should be implemented.

[Updated on: Tue, 24 September 2013 08:28] by Moderator

Re: Alternative types in cross references [message #1115682 is a reply to message #1115676]

Tue, 24 September 2013 08:31

Eclipse User

Hi,

maybe something like (pseudo code)

	IScope scope_X_y(EObject ctx, EReference ref) {
		Predicate<IEObjectDescription> filter = new Predicate<IEObjectDescription>() {

			@Override
			public boolean apply(IEObjectDescription arg0) {
				return TypesPackage.Literals.JVM_GENERIC_TYPE.isSuperTypeOf(arg0.getEClass())
						|| MydslPackage.Literals.XXX_YYY.isSuperTypeOf(arg0.getEClass());
			}
		};
		return new FilteringScope(delegateGetScope(ctx, ref), filter);
	}

Re: Alternative types in cross references [message #1115701 is a reply to message #1115682]

Tue, 24 September 2013 08:59

Eclipse User

Thanks a lot works perfect.
Here how it looks like implemented in Xtend (DeclarativeScopeProvider).

def IScope scope_ReferenceAttribute_type (EObject context, EReference ref) {
      return new FilteringScope (delegateGetScope (context, ref)) [
         return TypesPackage.Literals.JVM_GENERIC_TYPE.isSuperTypeOf (it.EClass) 
                || DomaindslPackage.Literals.DOMAIN_OBJECT.isSuperTypeOf (it.EClass)
      ]
}

Previous Topic:	Using DSL-Editor in an older Eclipse
Next Topic:	Problem with Super Grammar and an Ecore based SubGrammar

Goto Forum:

-=] Back to Top [=-

Current Time: Wed Jul 23 13:54:10 EDT 2025

.:: Contact :: Home ::.

Breadcrumbs

Sign up to our Newsletter