operation calculateRloc () : Integer {
	return daten!CompilationUnit.all().
		select(x | x.isSource()).
	 	collect(x | x.rloc()).
		sum().
		asInteger();	
}

operation CompilationUnit rloc() : Integer {
	var layouts = self.getChildrenByEType(AttributeLayoutInformation.createInstance().type());
	layouts.addAll(self.getChildrenByEType(KeywordLayoutInformation.createInstance().type()));
	layouts.addAll(self.getChildrenByEType(ReferenceLayoutInformation.createInstance().type()));
	return layouts.sortBy(x | x.getStartOffset()).
		collect(x | x.layoutAsText()).
		concat().
		split("\n").
		select(x | x.matches("(?s).*[a-zA-Z].*")).
		select(x | x <> "<EOF>").
		size();
}

operation LayoutInformation layoutAsText () : String {
	return self.getHiddenTokenText().
		toCharSequence().
		select(x | x="\n" or x="\t" or x=" " or x="\r").
		concat().
		concat(self.getVisibleTokenText());
}

@cached
operation Commentable isSource() : Boolean {
	if((self.eResource()).isUndefined()){
		return false;
	}
	return self.eResource().getURI().toString().startsWith('file:/');
}