override void doGenerate(Resource resource, IFileSystemAccess2 fsa, IGeneratorContext context) {
		val program = resource.contents.head as Program

		if (program !== null) {
			val programName = resource.URI.lastSegment.nameWithoutExtension.toFirstUpper

			AthenaUtilGenerator.generateUtilFile(resource, fsa, context)
			TurtleUtilGenerator.generateUtilFile(resource, fsa, context)

			fsa.generateTracedFile("generated/" + programName + ".java", program, '''
				package generated;
				
				import java.util.ArrayList;
				import java.util.Arrays;
				
				/*
				* Generated Java file, do not modify it!!!
				*/
				
				@SuppressWarnings("all")
				public class «programName» {
					static AthenaUtil util = new AthenaUtil();
					
					«FOR typeDec : program.typeDeclarations»
						«IF typeDec instanceof Composition»
							«fsa.generateTracedFile("generated/" + typeDec.name + ".java", program, '''
								package generated;
								/*
								* Generated Java file, do not modify it!!!
								*/
								public class «typeDec.name» {
									«FOR attr : (typeDec as Composition).attributes»
									«attr.generateAttribute»
									«ENDFOR»
								}
							''')»
						«ENDIF»
						«IF typeDec instanceof Enumeration»
							«fsa.generateTracedFile("generated/" + typeDec.name + ".java", program, '''
								package generated;
								/*
								* Generated Java file, do not modify it!!!
								*/
								public enum «typeDec.name» {
									«FOR value : (typeDec as Enumeration).values»
										«value.name.toUpperCase»
										«IF !(typeDec as Enumeration).values.get((typeDec as Enumeration).values.size-1).equals(value)», «ENDIF»
									«ENDFOR»
								}
							''')»
						«ENDIF»
					«ENDFOR»
					
					«FOR op : program.operations»
						«op.generateOperation»
					«ENDFOR»
					
					«IF program.mainBlock !== null»
						«program.mainBlock.generateMainMethod»
					«ENDIF»
				}
				
			''')
		}
	}

	@Traced def private generateOperation(Operation op) {
		'''
			«op.generateMethodSignature»{
				«FOR s : op.block.statements»
					«s.generateStatement»
				«ENDFOR»			
			}
		'''
	}

	def private generateStatement(Statement s) {
		val n = s.trace
		switch s {
			VariableDeclaration: {
				s.generateVariableDeclaration(n)
				n.append(";")
			}
			Assignment: {
				s.generateAssignment(n)
				n.append(";")
			}
			OperationCall: {
				s.generateOperationCall(n)
				n.append(";")
			}
			Conditional: {
				s.generateConditional(n)
			}
			WhileLoop: {
				s.generateWhileLoop(n)
			}
			ForEachLoop: {
				s.generateForEachLoop(n)
			}
			Return: {
				n.append("return ")
				s.expression.generateExpression(n)
				n.append(";")
			}
		}
		return n
	}