modeltype entities "strict" uses entities('example.com/entities');
modeltype persistence "strict" uses persistence('example.com/persistence');
modeltype uml "strict" uses uml('www.eclipse.org/uml2/3.0.0/UML');
(link problem, so there is no ht...)	

transformation swichprofile(in umlIn:entities, in persistenceProf:uml, out umlOut:persistence);

main() {
	-- copy root model(s)
	var _result := umlIn.rootObjects()[uml::Model].deepclone();
	_result[uml::Model]->forEach(model) {
		-- is "entities" Profile applied?
		if(model.getAppliedProfile('entities') <> null) then {
			-- remove application of "entities" profile
			model.unapplyProfile(model.getAppliedProfiles()![name='entities']);
			-- apply "persistence" profile instead
			model.applyProfile(persistenceProf.objectsOfType(uml::Profile)![name='persistence']);
		} endif;
	};
	-- now transform "entity" stereotype applications
	umlIn.objectsOfType(entities::Entity).map toPersistent();
	_result;
}

mapping entities::Entity::toPersistent() : persistence::Persistent {
	persistent_name := self.table_name;
	-- figure out which class the stereotype should be applied to
	base_Class := umlOut.objectsOfType(uml::Class)![qualifiedName = self.base_Class.qualifiedName];
}